tabsum

tabsum — Addition des valeurs dans un intervalle d'une table.

Description

Fait la somme des valeurs d'une ftable dans un intervalle contigu.

Syntaxe

kr tabsum ifn[[, kmin] [, kmax]]

Initialisation

ifn -- numéro de la table.

Exécution

kr -- signal retourné.

kmin, kmax -- intervalle de la table à sommer. S'il est omis ou si les arguments sont nuls, il couvre par défaut les valeurs allant de 0 à la longueur de la table.

Exemples

Voici un exemple de l'opcode tabsum. Il utilise le fichier tabsum.csd.

Exemple 1082. Exemple de l'opcode tabsum.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
-odac    ;;;realtime audio out
; For Non-realtime ouput leave only the line below:
; -o tab.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>

sr = 44100
ksmps = 2205
nchnls = 1
0dbfs  = 1

instr 1       ;;; Give a value to the increment
  kmax = 256
  knorm tabsum 1, 0, kmax
  gkinc = knorm/10
endin

instr 2
  kmax = 256
  kx = rnd(kmax)
  krnd  tabsum 1, 0, kx
  knorm tabsum 1, 0, kmax
  kvar  = krnd / knorm          ;;; now n [0,1] range
  asig  oscil  kvar, p4, 2
        out    asig
;;; Make randomness give 1 more often
  kc    tab     0, 1
        tablew  kc+gkinc, 0, 1
endin
</CsInstruments>

<CsScore>
f1 0 256 21 1  
f2 0 4096 10 1
i1 0 0.1
i2 0.1 3 440
e

</CsScore>

</CsoundSynthesizer>


Voir aussi

Vectorial opcodes

Crédits

Auteur : John ffitch
Codemist Ltd
2009

Nouveau dans la version 5.11