trigger

trigger — Informe quand un signal de taux-k traverse un seuil.

Description

Informe quand un signal de taux-k traverse un seuil.

Syntaxe

kout trigger ksig, kthreshold, kmode

Exécution

ksig -- signal d'entrée

kthreshold -- seuil de déclenchement

kmode -- peut valoir 0, 1 ou 2

Normalement trigger retourne des zéros : trigger retourne 1 chaque fois que ksig traverse kthreshold. Il y a trois modes d'utilisation de ktrig :

  • kmode = 0 - (bas-haut) ktrig retourne 1 lorsque la valeur courante de ksig est supérieure à kthreshold, alors que l'ancienne valeur de ksig était égale ou inférieure à kthreshold.

  • kmode = 1 - (haut-bas) ktrig retourne 1 lorsque la valeur courante de ksig est inférieure à kthreshold alors que l'ancienne valeur de ksig était égale ou supérieure à kthreshold.

  • kmode = 2 - (les deux) ktrig retourne 1 dans les deux cas précédents.

Exemples

Voici un exemple de l'opcode trigger. Il utilise le fichier trigger.csd.

Exemple 1022. Exemple de l'opcode trigger.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
-odac     ;;;realtime audio out
;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
; For Non-realtime ouput leave only the line below:
; -o trigger.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>

sr = 44100
ksmps = 32
nchnls = 2
0dbfs  = 1

instr 1

kmtr lfo 1, 1, 1			;triangle wave
kmode = p4
ktr  trigger kmtr, .5, kmode
     printk2  ktr
     schedkwhen ktr, 0, 3, 2, 0, .3


endin

instr 2                                            

aenv linseg 0,p3*.1,1,p3*.3,1,p3*.6,0	;envelope
a1   poscil .3*aenv, 1000, 1
     outs a1, a1

endin
</CsInstruments>
<CsScore>
f 1 0 16384 10 1	;sine 

i 1 0 3 0		;down-up
i 1 4 3 2		;down-up & up=down

e
</CsScore>
</CsoundSynthesizer>


Crédits

Auteur : Gabriel Maldonado
Italie

Nouveau dans la version 3.49 de Csound.