trmix

trmix — Mixage de flots de suivi de partiels.

Description

L'opcode trmix prend deux entrées contenant des flots de signal TRACKS pv (tels que générés, par exemple, par partials) et les mixe en un flot TRACKS unique. Les canaux sont mixés dans l'espace disponible (défini par le nombre original de bins de TFR dans les signaux analysés). Si la somme des canaux en entrée dépasse cet espace, les canaux d'ordre plus élevé dans la seconde entrée sont ignorés.

Syntaxe

fsig trmix fin1, fin2 

Exécution

fsig -- flot pv de sortie au format TRACKS.

fin1 -- premier flot pv d'entrée au format TRACKS.

fin2 -- second flot pv d'entrée au format TRACKS.

Exemples

Voici un exemple de l'opcode trmix. Il utilise le fichier trmix.csd.

Exemple 1026. Exemple de l'opcode trmix.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
-odac     ;;;realtime audio out
;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
; For Non-realtime ouput leave only the line below:
; -o trmix.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>

sr = 44100
ksmps = 32
nchnls = 2
0dbfs  = 1

instr 1

ain	diskin2	"fox.wav", 1
fs1,fsi2 pvsifd ain, 2048, 512, 1		; ifd analysis
fst	partials fs1, fsi2, .003, 1, 3, 500	; partial tracking
fslo,fshi trsplit fst, 1000			; split partial tracks at 1000 Hz
fscl	trscale	fshi, 1.3			; shift the upper tracks
fmix	trmix	fslo,fscl			; mix the shifted and unshifted tracks
aout	tradsyn	fmix, 1, 1, 500, 1		; resynthesis of tracks
	outs    aout, aout

endin
</CsInstruments>
<CsScore>
f1 0 8192 10 1	;sine wave

i 1 0 3
e
</CsScore>
</CsoundSynthesizer>


L'exemple ci-dessus montre le suivi de partiels d'un signal d'analyse par distribution de fréquence instantanée, la séparation en fréquence et la transposition de hauteur de la partie haute du spectre, suivies du remixage des deux parties du spectre et de la resynthèse.

Crédits

Auteur : Victor Lazzarini
Février 2006

Nouveau dans Csound 5.01