Instruction v

v — Permet une modification temporelle variable localement des évènements de la partition.

Description

L'instruction v permet une modification temporelle variable localement des évènements de la partition.

Syntaxe

v p1

Initialisation

p1 -- facteur de modification temporelle (doit être positif).

Exécution

L'instruction v prend effet avec l'instruction i qui la suit, et reste effective jusqu'à la prochaine instruction v, instruction s, ou instruction e.

Exemples

La valeur de p1 est utilisée comme un coefficient multiplicatif de la date de début (p2) des instructions i suivantes.

i1   0 1  ; note1
v2
i1   1 1  ; note2

Dans cet exemple, la deuxième note apparaît deux pulsations après la première note, et elle est deux fois plus longue.

Bien que l'instruction v soit semblable à l'instruction t, l'instruction v agit localement. Cela veut dire que v n'affecte que les notes suivantes, et que son effet peut être annulé ou changé par une autre instruction v.

Les valeurs reportées ne sont pas affectées par l'instruction v (voir Carry).

i1   0 1
v2
i.   + .
i.   . .

Dans cet exemple, l'instruction v n'a aucun effet.

Voici un exemple de l'instruction v. Il utilise le fichier v.csd.

Exemple 1122. Exemple de l'instruction v.

<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
-odac     ;;;realtime audio out
;-iadc    ;;;uncomment -iadc if RT audio input is needed too
; For Non-realtime ouput leave only the line below:
; -o v.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>

sr = 44100
ksmps = 32
nchnls = 2
0dbfs  = 1

instr 1

aenv expseg .01, p3*0.25, 1, p3*0.75, 0.01
asig poscil3 .4*aenv, p4, 1
     outs asig, asig

endin
</CsInstruments>
<CsScore>
f 1 0 16384 10 1	;sine wave
;because note 3 and 5 are played simultaneously and are nearly of the same frequency,
;played together they will create a "beating" sound.

i 1 0 2  110	; note1
v2
i 1 3 .  220	; note2
i 1 6 .  110	; note3
v1
i 1 9 .  880	; note4
i 1 12 . 100	; note5
e
</CsScore>
</CsoundSynthesizer>


Dans cet exemple, note3 et note5 sont jouées simulanément, tandis que note4 est jouée avant note3, c'est-à-dire à sa place initiale. Les durées sont inchangées.