wgbowedbar

wgbowedbar — Modèle physique d'une barre frottée.

Description

Modèle physique d'une barre frottée, appartenant à la famille des instruments à guide d'onde de Perry Cook.

Syntaxe

ares wgbowedbar kamp, kfreq, kpos, kbowpres, kgain [, iconst] [, itvel] \
      [, ibowpos] [, ilow]

Initialisation

iconst (facultatif, 0 par défaut) -- une constante d'intégration. Vaut zéro par défaut.

itvel (facultatif, 0 par défaut) -- 0 ou 1. Quand itvel = 0, la vitesse de l'archet suit une trajectoire de type ADSR. Quand itvel = 1, la valeur de la vélocité de l'archet décroit exponentiellement.

ibowpos (facultatif, 0 par défaut) -- la position sur l'archet, qui affecte la trajectoire de vélocité de l'archet.

ilow (facultatif, 0 par défaut) -- fréquence la plus basse désirée.

Exécution

kamp -- amplitude du signal.

kfreq -- fréquence du signal.

kpos -- position de l'archet sur la barre, comprise entre 0 et 1.

kbowpres -- pression de l'archet (comme dans wgbowed)

kgain -- gain du filtre. On recommande une valeur d'environ 0.809.

Exemples

Voici un exemple de l'opcode wgbowedbar. Il utilise le fichier wgbowedbar.csd.

Exemple 1119. Exemple de l'opcode wgbowedbar.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
-odac     ;;;realtime audio out
;-iadc    ;;;uncomment -iadc if RT audio input is needed too
; For Non-realtime ouput leave only the line below:
; -o wgbowedbar.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>

sr = 44100
ksmps = 32
nchnls = 2
0dbfs  = 1

instr 1

kp   = p6
asig wgbowedbar p4, cpspch(p5), 1, kp, 0.995
     outs asig, asig

endin
</CsInstruments>
<CsScore>
s
i1 0 .5 .5 7.00 .1	;short sound
i1 + .  .3 8.00 .1
i1 + .  .5 9.00 .1
s
i1 0 .5 .5 7.00  1	;longer sound
i1 + .  .3 8.00  1
i1 + .  .5 9.00  1
 
e
</CsScore>
</CsoundSynthesizer>


Crédits

Auteur : John ffitch (d'après Perry Cook)
Université de Bath, Codemist Ltd.
Bath, UK

Nouveau dans la version 4.07 de Csound