wguide1

wguide1 — Un modèle simple de guide d'onde constitué d'une ligne à retard et d'un filtre passe-bas du premier ordre.

Description

Un modèle simple de guide d'onde constitué d'une ligne à retard et d'un filtre passe-bas du premier ordre.

Syntaxe

ares wguide1 asig, xfreq, kcutoff, kfeedback

Exécution

asig -- l'entrée du bruit d'excitation.

xfreq -- la fréquence (c-à-d l'inverse de la durée du retard). A été changé au taux-x dans la version 3.59 de Csound.

kcutoff -- la fréquence de coupure du filtre en Hz.

kfeedback -- le facteur de rétroaction.

wguide1 est le modèle de guide d'onde le plus élémentaire, consistant en une ligne à retard et un filtre passe-bas du premier ordre.

L'implémentation des algorithmes de guide d'onde comme opcodes au lieu d'instruments d'un orchestre de Csound permet de fixer une valeur de kr différente de celle de sr, ce qui donne de meilleures performances particulièrement en .

wguide1.

wguide1.

Exemples

Voici un exemple de l'opcode wguide1. Il utilise le fichier wguide1.csd.

Exemple 1219. Exemple de l'opcode wguide1.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
; Audio out   Audio in
-odac             ;;;RT audio out
; For Non-realtime ouput leave only the line below:
; -o wguide1.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>

; by Kevin Conder
; additions by Menno Knevel 2021

sr = 44100
ksmps = 32
nchnls = 2
0dbfs  = 1

instr 1     ; Generate some noise.
  
asig noise .5, 0.5
outs asig, asig

endin

instr 2     
  
asig noise .5, 0.5                          ; Generate some noise.
kfreq line p4, p3, 100                      ; Run it through a wave-guide model.
kcutoff init 3000
kfeedback init 0.8
awg1 wguide1 asig, kfreq, kcutoff, kfeedback
outs awg1, awg1

endin

</CsInstruments>
<CsScore>
i 1 0 2
;           freq
i 2 2 5     2000    ; falling frequency
i 2 8 3     100     ; static
e
</CsScore>
</CsoundSynthesizer>


Voir aussi

wguide2

Crédits

Auteur : Gabriel Maldonado
Italie
Octobre 1998

Nouveau dans la version 3.49 de Csound.