zarg

zarg — Lecture à partir d'une position dans l'espace za au taux-a avec application d'un gain.

Description

Lecture à partir d'une position dans l'espace za au taux-a avec application d'un gain.

Syntaxe

ares zarg kndx, kgain

Initialisation

kndx -- pointe sur la position za à lire.

kgain -- Multiplicateur pour le signal taux-a.

Exécution

zarg lit la suite de nombres décimaux à kndx dans l'espace za, qui sont les ksmps nombres décimaux de taux-a à traiter dans un cycle-k. zarg multiplie aussi le signal de taux-a par la valeur de taux-k kgain.

Exemples

Voici un exemple de l'opcode zarg. Il utilise le fichier zarg.csd.

Exemple 1146. Exemple de l'opcode zarg.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
; Audio out   Audio in    No messages
-odac           -iadc     -d     ;;;RT audio I/O
; For Non-realtime ouput leave only the line below:
; -o zarg.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>

; Initialize the global variables.
sr = 44100
kr = 4410
ksmps = 10
nchnls = 1

; Initialize the ZAK space.
; Create 1 a-rate variable and 1 k-rate variable.
zakinit 1, 1

; Instrument #1 -- a simple waveform.
instr 1
  ; Generate a simple sine waveform, with an amplitude 
  ; between 0 and 1.
  asin oscil 1, 440, 1

  ; Send the sine waveform to za variable #1.
  zaw asin, 1
endin

; Instrument #2 -- generates audio output.
instr 2
  ; Read za variable #1, multiply its amplitude by 20,000.
  a1 zarg 1, 20000

  ; Generate audio output.
  out a1

  ; Clear the za variables, get them ready for 
  ; another pass.
  zacl 0, 1
endin


</CsInstruments>
<CsScore>

; Table #1, a sine wave.
f 1 0 16384 10 1

; Play Instrument #1 for one second.
i 1 0 1
; Play Instrument #2 for one second.
i 2 0 1
e


</CsScore>
</CsoundSynthesizer>


Voir aussi

zar, zir, zkr

Crédits

Auteur : Robin Whittle
Australie
Mai 1997

Nouveau dans la version 3.45

Exemple écrit par Kevin Conder.