STKBlowBotl

STKBlowBotl — STKBlowBotl uses a helmholtz resonator (biquad filter) with a polynomial jet excitation.

Description

Plugin opcode in stkopd. This opcode is part of the plugin repository and has to be installed separately. The plugin repository can be found here: https://github.com/csound/plugins

This opcode implements a helmholtz resonator (biquad filter) with a polynomial jet excitation (a la Cook).

Syntax

asignal STKBlowBotl ifrequency, iamplitude, [knoise, kv1[, klfo, kv2[, klfodepth, kv3[, kvol, kv4]]]]

Initialization

ifrequency -- Frequency of note played, in Hertz.

iamplitude -- Amplitude of note played (range 0-1).

Performance

knoise -- controller 4, gain of noise. Value range of kv1 is 0-127.

klfo -- controller 11, speed of low-frequency oscillator. Value range of kv2 is 0-127.

klfodepth -- controller 1, depth of low-frequency oscillator. Value range of kv3 is 0-127.

kvol -- controller 128, volume. Value range of kv4 is 0-127.

[Note] Notes

The code for this opcode is taken directly from the BlowBotl class in the Synthesis Toolkit in C++ by Perry R. Cook and Gary P. Scavone. More on the STK classes can be found here: https://ccrma.stanford.edu/software/stk/classes.html

kc1, kv1, kc2, kv2, kc3, kv3, kc4, kv4, kc5, kv5, kc6, kv6, kc7, kv7, kc8, kv8 -- Up to 8 optional k-rate controller pairs for the STK opcodes. Each controller pair consists of a controller number (kc) followed by a controller value (kv). Both the controller numbers and the controller values are krate variables. However, during a performance, normally the controller numbers stay fixed while the corresponding controller values may change at any time. The order of the controller pair is arbitrary, as long as they are after iamplitude. Also, it is not needed that all controller pairs are used.

Examples

Here is an example of the STKBlowBotl opcode. It uses the file STKBlowBotl.csd.

Example 1012. Example of the STKBlowBotl opcode.

<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
-odac     ;;;realtime audio out
;-iadc    ;;;uncomment -iadc if RT audio input is needed too
; For Non-realtime ouput leave only the line below:
; -o STKBlowBotl.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>

sr = 44100
ksmps = 32
nchnls = 2
0dbfs  = 1

instr 1

ipch	= p4
kv1	line p5, p3, p6					;gain of noise
kv4	line	100, p3, 70				;volume

asig	STKBlowBotl cpspch(ipch), 1, 4, kv1, 11, 10, 1, 50, 128, kv4
asig	=	asig * .5				;too loud
	outs	asig, asig
endin

</CsInstruments>
<CsScore>

i 1 0 2 9.00 20 100
i 1 + 5 8.03 120 0
e
</CsScore>
</CsoundSynthesizer>


Credits

Author: Michael Gogins (after Perry Cook)
Irreducible Productions
New York, NY

New in Csound version 5.11