inletk

inletk — Receives a krate signal into an instrument from a named port.

Description

Plugin opcode in signalflowgraph

Receives a krate signal into an instrument from a named port.

Syntax

ksignal inletk Sname

Initialization

Sname -- String name of the inlet port. The name of the inlet is implicitly qualified by the instrument name or number, so it is valid to use the same inlet name in more than one instrument (but not to use the same inlet name twice in one instrument).

Performance

ksignal -- krate input signal

During performance, the krate inlet signal is received from each instance of an instrument containing an outlet port to which this inlet has been connected using the connect opcode. The signals of all the outlets connected to an inlet are summed in the inlet.

Examples

Here is an example of the inletk opcode. It uses the file inletk.csd.

Example 471. Example of the inletk opcode.

<CsoundSynthesizer> 
<CsOptions>
; Select audio/midi flags here according to platform
-odac     ;;;realtime audio out
;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
; For Non-realtime ouput leave only the line below:
; -o inletk.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments> 

sr = 44100
ksmps = 32
nchnls = 2
0dbfs  = 1

connect "bend", "bendout", "guitar", "bendin" 

instr bend 

kbend line p4, p3, p5 

printk2 kbend
      outletk "bendout", kbend 

endin 

instr guitar 

kbend inletk "bendin" 
kpch pow 2, kbend/12
asig oscili .4, p4*kpch, 1 
     outs asig, asig
endin 

</CsInstruments> 
<CsScore> 
f1 0 1024 10 1 0 1 0 1 0 1

i"guitar" 0  5   440
i"bend"   2 1.2 -12 12 
i"bend"   4 .2  -17 40 
e
</CsScore> 


See Also

outleta outletk outletkid outletf inleta inletf connect alwayson ftgenonce

Credits

By: Michael Gogins 2009