mvclpf1

mvclpf1 — Moog voltage-controlled lowpass filter emulation.

Description

Mvclpf1 is an digital implementation of the 4th-order (24 dB/oct) Moog ladder filter originally written by Fons Andriaensen. According to the author, mvclpf1 "is a fairly simple design, and it does not even pretend to come close the 'real thing'. It uses a very crude approximation of the non-linear resistor in the first filter section only. [...] [I]t's [a] cheap (in terms of CPU usage) general purpose 24 dB/oct lowpass filter that could be useful".

Syntax

asig mvclpf1 ain, xcf, xres[,istor]

Initialization

istor --initial disposition of internal data space. Since filtering incorporates a feedback loop of previous output, the initial status of the storage space used is significant. A zero value will clear the space; a non-zero value will allow previous information to remain. The default value is 0.

Performance

ain -- input signal.

xcf -- filter cutoff frequency. The useful range is around six octaves below and above middle C (pch 8.00).

xres -- resonance, limited to the interval [0,1].

Examples

Here is an example of the mvclpf1 opcode. It uses the file mvclpf1.csd.

Example 559. Example of the mvclpf1 opcode.

See the sections Real-time Audio and Command Line Flags for more information on using command line flags.

<CsoundSynthesizer>
<CsOptions>
-odac 
</CsOptions>
<CsInstruments>
0dbfs = 1

instr 1
 kenv linen p4,0.1,p3,0.1
 ain rand kenv 
 kfr expon 220, p3, 1760
 asig mvclpf1 ain,kfr,0.9
   out asig
endin

</CsInstruments>
<CsScore>
i1 0 5 0.9
</CsScore>
</CsoundSynthesizer>


Credits

Author: Fons Andriaensen,
ported to Csound by Victor Lazzarini
January 2016

New in version 6.07

January 2016.