dcblock2

dcblock2 — Un filtre bloqueur de composante continue.

Description

Implémente un filtre bloqueur de composante continue avec une atténuation améliorée de la composante continue.

Syntaxe

ares dcblock2 ain [, iorder] [, iskip]

Initialisation

iorder -- ordre du filtre, au minimum 4ème ordre, vaut par défaut 128.

iskip -- s'il vaut 1, l'initialisation est ignorée (0 par défaut).

Exécution

ares -- signal audio filtré

ain -- signal audio en entrée

[Note] Note

Avec l'utilisation d'une valeur inférieure à ksmps pour iorder, la réduction du décalage dû à la composante continue ne sera pas efficace.

Exemples

On peut voir le résultat dans un éditeur graphique de fichiers audio comme audacity. audacity est disponible pour Linux, Windows et Mac OS et on peut le télécharger depuis http://audacity.sourceforge.net.

Voici un exemple de l'opcode dcblock2. Il utilise les fichiers dcblock2.csd et beats.wav.

Exemple 183. Exemple de l'opcode dcblock2.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
-odac     ;;;RT audio out
;-iadc    ;;;uncomment -iadc if RT audio input is needed too
; For Non-realtime ouput leave only the line below:
;-o dcblock2.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>

sr = 44100
ksmps = 32
nchnls = 2

instr 1	;add DC to "beats.wav"

asig soundin "beats.wav"
asig = asig+5000	;adds DC of 5000
     outs asig, asig
endin

instr 2	;dcblock audio

asig soundin "beats.wav"
asig = asig+5000	;adds DC
adc  dcblock2 asig	;remove DC again
     outs adc, adc

endin

</CsInstruments>
<CsScore>

i 1 0 2
i 2 2 2
e

</CsScore>
</CsoundSynthesizer>


Voir aussi

dcblock

Crédits

Par Victor Lazzarini

Nouveau dans la version 5.09 de Csound