fin

fin — Lit des signaux depuis un fichier au taux-a.

Description

Lit des signaux depuis un fichier au taux-a.

Syntaxe

fin ifilename, iskipframes, iformat, ain1 [, ain2] [, ain3] [,...]
fin ifilename, iskipframes, iformat, arr[]

Initialisation

ifilename -- nom du fichier d'entrée (peut être une chaîne de caractères ou un identificateur numérique généré par fiopen).

iskipframes -- nombre de trames à ignorer au début (chaque trame contient un échantillon de chaque canal).

iformat -- un nombre spécifiant le format du fichier d'entrée pour les fichiers sans en-tête. Si un en-tête est trouvé, cet argument est ignoré.

  • 0 - flottants sur 32 bit sans en-tête

  • 1 - entiers sur 16 bit sans en-tête

Exécution

fin (file input) est le complément de fout : il lit un fichier multicanaux pour générer des signaux de taux audio. Il faut s'assurer que le nombre de canaux du fichier d'entrée est le même que le nombre d'arguments ainX.

[Note] Note

Prière de noter que comme cet opcode génére sa sortie en utilisant des paramètres d'entrée (placés à droite de l'opcode), ces variables doivent avoir été initialisées avant leur utilisation, sinon une erreur "utilisé avant d'être défini" se produira. On peut utiliser l'opcode init pour cela.

Exemples

Voici un exemple de l'opcode fin. Il utilise les fichiers fin.csd et fox.wav.

Exemple 272. Exemple de l'opcode fin.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
-odac     ;;;realtime audio out
;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
; For Non-realtime ouput leave only the line below:
; -o fin.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>

sr = 44100
ksmps = 32
nchnls = 2
0dbfs  = 1

instr 1 

asnd init 0 			;input of fin must be initialized
     fin  "fox.wav", 0, 0, asnd	;read audiofile
aenv follow asnd, 0.01		;envelope follower
kenv downsamp aenv
asig rand kenv			;gate the noise with audiofile
     outs asig, asig 
endin 

</CsInstruments>
<CsScore>

i 1 0 3
e

</CsScore>
</CsoundSynthesizer>


Voir aussi

fini, fink

Crédits

Auteur : Gabriel Maldonado
Italie
1999
Author: John ffitch
NUIM, 2013

Nouveau dans la version 3.56 de Csound

Variante pour tableau ajoutée dans la version 6.01