pchbend

pchbend — Donne la valeur actuelle du pitch-bend pour ce canal.

Description

Donne la valeur actuelle du pitch-bend pour ce canal.

Syntaxe

ibend pchbend [imin] [, imax]
kbend pchbend [imin] [, imax]

Initialisation

imin, imax (optionel) -- fixe les limites minimale et maximale pour les valeurs obtenues

Exécution

Donne la valeur actuelle du pitch-bend pour ce canal. Noter que l'on a la valeur du pitch-bend qui est indépendant du pitch MIDI, ce qui permet d'utiliser cette valeur pour n'importe quel but.

Exemples

Voici un exemple de l'opcode pchbend. Il utilise le fichier pchbend.csd.

Exemple 637. Exemple de l'opcode pchbend.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
-odac -Q1 -Ma  ;;;realtime audio out and midi in (on all inputs) and out
;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
; For Non-realtime ouput leave only the line below:
; -o pchbend.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>
 

sr = 44100
ksmps = 32
nchnls = 2
0dbfs  = 1

instr   1	;use external midi keyboard

icps cpsmidi
kbnd pchbend 0, 100					;one octave lower and higher
kenv linsegr 0,.001, 1, .1, 0				;amplitude envelope 
asig pluck .8 * kenv, icps+kbnd, 440, 0, 1
     outs asig, asig

endin 
</CsInstruments>
<CsScore>
 

f 0 30	;runs 30 seconds
 
</CsScore>
</CsoundSynthesizer>


Voir aussi

aftouch, ampmidi, cpsmidi, cpsmidib, midictrl, notnum, octmidi, octmidib, pchmidi, pchmidib, veloc

Crédits

Auteur : Barry L. Vercoe - Mike Berry
MIT - Mills
Mai 1997