Instruction t (instruction de tempo)

t — Fixe le tempo.

Description

Cette instruction fixe le tempo et spécifie les accelerando et les ritardando de la section courante. Ceci est réalisé en convertissant les pulsations en secondes.

Syntaxe

t  p1  p2  p3  p4 ... (illimité)

Initialisation

p1 -- Doit être zéro.

p2 -- Tempo initial en pulsations par minute.

p3, p5, p7,... -- Dates en pulsations (en ordre non décroissant).

p4, p6, p8,... -- Tempi pour les dates en pulsations référencées.

Exécution

Les dates et le Tempo pour chaque date sont donnés en couples ordonnés qui définissent des points sur un graphe « date, tempo ». (L'axe du temps est ici en pulsations et n'est donc pas nécessairement linéaire). Le taux de pulsations d'une section peut être pensé comme un mouvement d'un point à un autre de ce graphe : un mouvement entre deux points à la même hauteur signifie un tempo constant, tandis qu'un mouvement entre deux points de hauteurs différentes traduit un accelerando ou un ritardando selon le cas. Le graphe peut contenir des discontinuités : deux points ayant la même date mais des tempi différents provoqueront un changement de tempo instantané.

Le mouvement entre différents tempi sur des durées non nulles est inversement linéaire. Cela veut dire qu'un accelerando entre deux tempi M1 et M2 procède par interpolation linéaire des durées de chaque pulsation entre 60/M1 et 60/M2.

Le premier tempo doit être donné pour la pulsation 0.

Une fois assigné, un tempo sera effectif à partir de cette date à moins d'être influencé par un tempo suivant, ainsi, le dernier tempo spécifié sera actif jausqu'à la fin de la section.

Une instruction t ne s'applique que dans la section dans laquelle elle apparaît. Une seule instruction t est pertinente dans une section ; elle peut être placée n'importe où dans la section. Si une section de partition ne contient pas d'instruction t, les pulsations sont alors interprétées comme des secondes (c'est-à-dire avec une instruction t 0 60 implicite).

Nota Bene. Si la commande de Csound comprend une option -t, le tempo interprété de toutes les instruction t de la partition sera remplaçé par le tempo de la ligne de commande.

Exemples

Voici un exemple de l'instruction t. Il utilise le fichier t.csd.

Exemple 1172. Exemple de l'instruction t.

<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
-odac     ;;;realtime audio out
;-iadc    ;;;uncomment -iadc if RT audio input is needed too
; For Non-realtime ouput leave only the line below:
; -o t.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>

sr = 44100
ksmps = 32
nchnls = 2
0dbfs  = 1

instr 1

aenv expseg .01, p3*0.25, 1, p3*0.75, 0.01
asig poscil3 .8*aenv, p4, 1
     outs asig, asig

endin
</CsInstruments>
<CsScore>
f 1 0 16384 10 1	;sine wave

t 0 240 12 30 15 240	;start tempo = 240 
		
i 1 0 2 110		;tempo = 240
i 1 3 2 220		;slow down &
i 1 6 2 440		;slow down &
i 1 9 2 880		;slow down &		
i 1 12 2 110		;slow down to 30 at 12 seconds
i 1 15 2 220		;speed up to 240 again
i 1 18 2 440		;stay at tempo 240
i 1 21 2 880
e
</CsScore>
</CsoundSynthesizer>