wgbrass

wgbrass — Simule un son de cuivre.

Description

La sortie audio simule un son de cuivre, réalisé au moyen d'un modèle physique développé par Perry Cook, mais recodé pour Csound.

Syntaxe

ares wgbrass kamp, kfreq, ktens, iatt, kvibf, kvamp \
    [, ifn] [, iminfreq]

Initialisation

iatt -- temps requis pour atteindre la pression nominale.

ifn -- table facultative contenant la forme du vibrato, par défaut une table de sinus.

iminfreq -- (facultatif) -- fréquence la plus grave à laquelle l'instrument sera joué. Si elle est omise, elle prend la valeur initiale de kfreq. Si iminfreq est négative, l'initialisation est ignorée.

Exécution

Une note est jouée sur un instrument de type cuivre, avec les arguments ci-dessous.

kamp -- Amplitude de la note.

kfreq -- Fréquence de la note jouée.

ktens -- Tension des lèvres de l'instrumentiste. La valeur recommandée vaut environ 0.4.

kvibf -- Fréquence du vibrato en Hz. L'intervalle recommandé va de 0 à 12.

kvamp -- amplitude du vibrato

[Avertissement] NOTE

Ceci est assez pauvre et non contrôlable. Il faut une révision, et probablement plus de paramètres.

Exemples

Voici un exemple de l'opcode wgbrass. Il utilise le fichier wgbrass.csd.

Exemple 1120. Exemple de l'opcode wgbrass.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
; Audio out   Audio in    No messages
-odac           -iadc     -d     ;;;RT audio I/O
; For Non-realtime ouput leave only the line below:
; -o wgbrass.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>

; Initialize the global variables.
sr = 44100
ksmps = 10
nchnls = 1
0dbfs = 1

; Instrument #1.
instr 1
  kamp = 0.7
  kfreq = p4
  ktens = p5
  iatt = p6
  kvibf = p7
  ifn = 1

  ; Create an amplitude envelope for the vibrato.
  kvamp line 0, p3, 0.5

  a1 wgbrass kamp, kfreq, ktens, iatt, kvibf, kvamp, ifn
  out a1
endin


</CsInstruments>
<CsScore>

; Table #1, a sine wave.
f 1 0 1024 10 1

;        freq   tens  att  vibf
i 1 0 4  440    0.4   0.1  6.137
i 1 4 4  440    0.4   0.01 0.137
i 1 8 4  880    0.4   0.1  6.137
e


</CsScore>
</CsoundSynthesizer>


Crédits

Auteur : John ffitch (d'après Perry Cook)
Université de Bath, Codemist Ltd.
Bath, UK

Nouveau dans la version 3.47 de Csound

ifn est devenu facultatif dans la version 6.06