wrap

wrap — Enroule le signal qui dépasse les limites inférieure ou supérieure.

Description

Enroule le signal qui dépasse les limites inférieure ou supérieure.

Syntaxe

ares wrap asig, klow, khigh
ires wrap isig, ilow, ihigh
kres wrap ksig, klow, khigh

Initialisation

isig -- signal d'entrée

ilow -- limite inférieure

ihigh -- limite supérieure

Exécution

xsig -- signal d'entrée

klow -- limite inférieure

khigh -- limite supérieure

wrap enroule le signal qui dépasse les limites inférieure ou supérieure.

Cet opcode est utile dans plusieurs situations, telles que l'indexation de table ou pour l'écrêtage et le modelage de signaux de taux-a, de taux-i ou de taux-k. wrap est aussi utile pour le parcours cyclique de tables quand l'indice maximum n'est pas une puissance de deux (voir table et tablei). Une autre utilisation de wrap consiste à répéter des évènements de manière cyclique, avec une longueur de cycle arbitraire.

Exemples

Voici un exemple de l'opcode wrap. Il utilise le fichier wrap.csd.

Exemple 1131. Exemple de l'opcode wrap.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
-odac    ;;;realtime audio out
;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
; For Non-realtime ouput leave only the line below:
; -o wrap.wav -W  ;;; for file output any platform
</CsOptions>
<CsInstruments>

sr = 44100 
ksmps = 32 
0dbfs  = 1 
nchnls = 2

instr    1 ; Limit / Mirror / Wrap

igain    = p4				;gain
ilevl1   = p5				; + level
ilevl2   = p6				; - level
imode    = p7				;1 = limit, 2 = mirror, 3 = wrap

ain   soundin  "fox.wav"
ain   = ain*igain

if    imode = 1 goto limit
if    imode = 2 goto mirror

asig  wrap  ain, ilevl2, ilevl1
goto  outsignal

limit:
asig  limit  ain, ilevl2, ilevl1
goto  outsignal

mirror:
asig  mirror  ain, ilevl2, ilevl1
outsignal:

outs  asig*.5, asig*.5			;mind your speakers
  
endin

</CsInstruments>
<CsScore>

;           Gain  +Levl -Levl Mode
i1  0  3    4.00  .25  -1.00   1	;limit
i1  4  3    4.00  .25  -1.00   2	;mirror
i1  8  3    4.00  .25  -1.00   3	;wrap
e
</CsScore>
</CsoundSynthesizer>


Voir aussi

limit, mirror

Crédits

Auteur : Gabriel Maldonado
Italie

Nouveau dans la version 3.49 de Csound