filenchnls

filenchnls — Retourne le nombre de canaux d'un fichier son.

Description

Retourne le nombre de canaux d'un fichier son.

Syntaxe

ir filenchnls ifilcod [, iallowraw]

Initialisation

ifilcod -- fichier son à interroger

iallowraw -- (facultatif) permet des fichiers son bruts (vaut 1 par défaut)

Exécution

filenchnls retourne le nombre de canaux du fichier son ifilcod. filenchnls peut retourner le nombre de canaux des fichiers de type convolve et PVOC si le paramètre iallowraw est différent de zéro (il est non nul par défaut).

Exemples

Voici un exemple de l'opcode filenchnls. Il utilise les fichiers filenchnls.csd, fox.wav et kickroll.wav.

Exemple 264. Exemple de l'opcode filenchnls.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
;-odac     ;;;realtime audio out
-iadc    ;;;uncomment -iadc if realtime audio input is needed too
; For Non-realtime ouput leave only the line below:
;-o filechnls.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>

sr = 44100
ksmps = 32
nchnls = 2
0dbfs = 1

instr 1 ; choose between mono or stereo file

ilen   filelen p4	;calculate length of soundfile
;print  ilen
ichn filenchnls  p4	;check number of channels
print  ichn

if (ichn == 1) then
;mono signal
asig diskin2 p4, 1	
     outs    asig, asig

else
;stereo signal
aL, aR diskin2 p4, .5, 0, 1 
       outs    aL, aR

endif

endin
</CsInstruments>
<CsScore>

i 1 0 3 "fox.wav"	;mono signal
i 1 5 2 "kickroll.wav"	;stereo signal

e
</CsScore>
</CsoundSynthesizer>


Le fichier audio « fox.wav » est monophonique (1 canal), tandis que « kickroll.wav » est stéréophonique (2 canaux). Ainsi la sortie de filenchnls contiendra des lignes comme :

instr 1:  ichn = 1.000
instr 1:  ichn = 2.000

Voir aussi

filebit, filelen, filepeak, filesr

Crédits

Auteur : Matt Ingalls
Juillet 1999

Nouveau dans la version 3.57 de Csound