filepeak

filepeak — Retourne la valeur absolue de la crête d'un fichier son.

Description

Retourne la valeur absolue de la crête d'un fichier son.

Syntaxe

ir filepeak ifilcod [, ichnl]

Initialisation

ifilcod -- fichier son à interroger

ichnl (facultatif, 0 par défaut) -- canal sur lequel la valeur de crête est calculée. La valeur par défaut est 0.

  • ichnl = 0 retourne la valeur de crête de tous les canaux

  • ichnl > 0 retourne la valeur de crête de ichnl

Exécution

filepeak retourne la valeur absolue de la crête du fichier son ifilcod.

Exemples

Voici un exemple de l'opcode filepeak. Il utilise les fichiers filepeak.csd et Church.wav.

Exemple 270. Exemple de l'opcode filepeak.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
-odac      ;;;realtime audio out
;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
; For Non-realtime ouput leave only the line below:
; -o filepeak.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>

sr = 44100
ksmps = 32
nchnls = 2
0dbfs  = 1

instr 1 

iscaldb = p4 ;set peak amplitude in dB
ipeak   filepeak "Church.wav"
iscal   = ampdb(iscaldb)/ipeak ;calculate amp multiplier
printf_i "\nPeak value in file '%s' is %f (%.3f dB).\n\n", 1, "Church.wav", ipeak, dbamp(ipeak)

asnd soundin "Church.wav"
     outs asnd, asnd
; scale & write file to disk
asig = asnd*iscal ;scale to p4
fout "Church_norm.wav", 14, asig

endin

instr 2 ; play scaled file

aout   soundin  "Church_norm.wav"
ipknew filepeak "Church_norm.wav"
printf_i "\nPeak value in file '%s' is %f (%.3f dB).\n\n", 1, "Church_norm.wav", ipknew, dbamp(ipknew)
       outs aout, aout

endin
</CsInstruments>
<CsScore>

i 1 0 2 -6 ; normalize audio to -6 dB
i 2 2 2
e
</CsScore>
</CsoundSynthesizer>


La sortie de filepeak contiendra des lignes comme celles-ci :

Peak value in file 'Church.wav' is 0.909363 (-0.825 dB).
Peak value in file 'Church_norm.wav' is 0.501190 (-6.000 dB).

Voir aussi

filelen, filenchnls, filesr

Crédits

Auteur : Matt Ingalls
Juillet 1999

Exemple écrit par Kevin Conder.

Nouveau dans la version 3.57 de Csound